//Bob Dougherty August 22, 2010
//Updated January 16, 2011
//Process all datasets in a folder
//Intended for Beamforming Interactive version January 14 2010 or later.

requires("1.34m");
methods = newArray("[Wide Band Conventional]","[Frequency Domain BeamForming]",
           "[TIDY]","[CLEAN-SC]","[DAMAS2]","[Nearfield Acoustic Holography]","MUSIC","[Orthogonal Beamforming]");
outputs = newArray("[Tiff]","[AVI]","[None]");
results = newArray("[Tab delimited]","[Comma Separated Values]","[None]");
docs = newArray("[Save Preference Files]","[No Documenetaton]");
sweeps = newArray("[Frequency]","[Time]","[z]","[None]");
comm = "BF";

Dialog.create("BI Batch");
Dialog.addChoice("Method:", methods);
Dialog.addString("comment", comm);
Dialog.addChoice("Sweep:", sweeps);
Dialog.addChoice("Image_format:", outputs);
Dialog.addChoice("Results_format:", results);
Dialog.addChoice("Documentation Files:", docs);
Dialog.show();
method = Dialog.getChoice();
comm = "["+Dialog.getString()+"]";
sweep = Dialog.getChoice();
image = Dialog.getChoice();
result = Dialog.getChoice();
doc =  Dialog.getChoice();

dir1 = getDirectory("Choose Data Directory");
if(image=="[None]"){
	outputImageDirectory = "[]";
}else{
	outputImageDirectory = "["+getDirectory("Choose destination directory for images")+"]";
}
if(result=="[None]"){
	outputResultsDirectory = "[]";
}else{
	outputResultsDirectory = "["+getDirectory("Choose destination directory for Results tables")+"]";
}
if(doc=="[No Documenetaton]"){
	outputDocsDirectory = "[]";
}else{
	outputDocsDirectory = "["+getDirectory("Choose destination directory for documentation preference files")+"]";
}
list = getFileList(dir1);
for(i=0; i<list.length; i++) {
	for(j=0; j<list.length; j++){
		if(i!=j){
			if(endsWith(list[i],".avi")&endsWith(list[j],".wav")){
				if(lengthOf(list[i])==lengthOf(list[j])){
					if(substring(list[i], 0, 14) == substring(list[j], 0, 14)){
						picture = "["+dir1 + list[i]+"]";
						data =  "["+dir1 + list[j]+"]";
						runBI();
					}
				}
			}
		}
	}
}
function runBI(){
	run("Beamform Interactive",
	"method="+method+
	" picture_file="+picture+	
	" data_file="+data+
	" picture_crop_roi_file="+"[]"+
	" sweep="+sweep+
	" beamforming_roi_file="+"[]"+
	" comment="+comm+
	" output_image_directory="+outputImageDirectory+
	" stack_format="+image+
	" output_results_directory="+outputResultsDirectory+
	" results_table_format="+result+
	" output_documentation_directory="+outputDocsDirectory
	);
}